Problem for the MITP school

At 4 pt, we have (4 - 1)!=6 independent orderings of the the 4 generators in the color order expansion:
1234, 1243, 1324, 1343, 1423, 1432. This gives 36 different matrix elements for the bi-adjoint scalar amplitudes m[a|b]. 

For this problem, we make the simplifying assumption that trace-reversal holds for the amplitudes:
That means orderings like 4321 are equivalent to 1234 which by cyclic symmetry relates 1432 to 1234. That way we only need a 3x3 matrix of doubly color-ordered amplitudes.

We introduce functions f1 and f2 as

m[1234|1432] = m[1234|1234] =  f1[s,t]
m[1234|1342] = m[1234|1243] = f2[s,t]
m[1234|1423] = m[1234|1324] = f3[s,t] = f2[-s-t,t]
 
with    f1[s,t]=f1[-s-t,t]

Set up useful s, t 4-pt numerics

(this is helpful for automatic comparison of s, t, u expressions)

stNumerics[seed_]:=(SeedRandom[seed];{s->(RandomInteger[{-1000,1000}]+1/4)/(RandomInteger[{-1000,1000}]+1/3),t->(RandomInteger[{-1000,1000}]+1/4)/(RandomInteger[{-1000,1000}]+1/3)})

Bi - adjoint scalar amplitudes

PROBLEM 0

Build the 3x3 matrix

BasisEl={{2,3,4},{2,4,3},{3,2,4}};

A4matrix=Table[A4[ii,jj],{ii,BasisEl},{jj,BasisEl}];
A4matrix//MatrixForm

VectorOfPerms={{1->1},{3->4,4->3},{3->2,2->3},{3->2,2->4,4->3},{4->2,2->3,3->4},{4->2,2->4}};

VectorOfInvPerms={{1->1},{3->4,4->3},{3->2,2->3},{4->2,2->3,3->4},{3->2,2->4,4->3},{4->2,2->4}};

preprematrix=Table[A4[BasisEl[[ii]]/.VectorOfPerms[[ii]],BasisEl[[jj]]/.VectorOfPerms[[ii]]],{ii,1,3},{jj,1,3}];
preprematrix//MatrixForm

Check

Table[(preprematrix[[k]]/.VectorOfInvPerms[[k]])-A4matrix[[k]],{k,1,3}]

AmpsRule={A4[{2,3,4},{2,3,4}]->F1[S[2],S[3]],A4[{2,3,4},{2,4,3}]->F2[S[2],S[3]],A4[{2,3,4},{3,2,4}]->F3[S[2],S[3]],A4[{2,3,4},{3,4,2}]->F4[S[2],S[3]],A4[{2,3,4},{4,2,3}]->F5[S[2],S[3]],A4[{2,3,4},{4,3,2}]->F6[S[2],S[3]]};

sij2stRule={S[2]->s,S[3]->t,S[4]->-s-t};

prematrix=Table[preprematrix[[k]]/.AmpsRule/.VectorOfInvPerms[[k]],{k,1,3}]/.sij2stRule;

prematrix//MatrixForm

f2[s, t] = f3[-s - t, t] = f4[s, t] = f5[-s - t, t]

ff345Toff2rule:={F4[s_,t_]:>F2[s,t],F3[s_,t_]:>F2[-s-t,t],F5[s_,t_]:>F2[-s-t,t]}

The3x3matrix=prematrix/.ff345Toff2rule;

The3x3matrix

The3x3matrix//MatrixForm

The3x3matrix/.-s-t->u//MatrixForm

PROBLEM 1: Standard field theory double-copy with BAS amplitudes

PROBLEM 1a: Test rank 1 of BAS amplitudes

f1BAS[s_,t_]:=(((g^2)/s)+((g^2)/(-s-t)))

f2BAS[s_,t_]:=-((g^2)/s)

The3x3matrix/.F1->f1BAS/.F2->f2BAS/.-s-t->u//MatrixForm

MatrixRank[The3x3matrix/.F1->f1BAS/.F2->f2BAS]

PROBLEM 1b: Null vectors

The null vector of the U (1) decoupling identity is

nullU1={1,1,1};

The3x3matrix.nullU1/.F1->f1BAS/.F2->f2BAS

nullU1.The3x3matrix/.F1->f1BAS/.F2->f2BAS

The3x3matrix.nullU1/.F1->f1BAS/.F2->f2BAS

It IS a null vector!

The null vector of the BCJ relation is

nullBCJ={1,-t/(-s-t),0};

Simplify[The3x3matrix.nullBCJ/.F1->f1BAS/.F2->f2BAS]

Simplify[nullBCJ.The3x3matrix/.F1->f1BAS/.F2->f2BAS]

It IS a null vector!

PROBLEM 1c: χPT

A4χPT12340[s_,t_]:=c0 t

A4χPT12430[s_,t_]:=A4χPT12340[s,-s-t]

A4χPT13240[s_,t_]:=A4χPT12340[t,s]

A4χPTvec0={A4χPT12340[s,t],A4χPT12430[s,t],A4χPT13240[s,t]};

Simplify[nullU1.A4χPTvec0]

Simplify[nullBCJ.A4χPTvec0]

So the 2 - derivative χPT 4-pt amplitude solves the field theory KKBCJ relations.

PROBLEM 1d: double-copy χPT x χPT = special Galileon

Set it up so we can also use different ranks for Problem 2.

Extract a minor from the 3x3 matrix:

DefMinor[row_,col_]:=Table[The3x3matrix[[r,c]],{r,row},{c,col}]

DoubleCopyBasisChoice0[Lco_,Rco_]:=Simplify[Table[A4χPTvec0[[α]],{α,Lco}].(Inverse[DefMinor[Rco,Lco]/.F1->f1BAS/.F2->f2BAS].Table[A4χPTvec0[[β]],{β,Rco}])]

Test basis indep

Table[DoubleCopyBasisChoice0[{1},{1}]-DoubleCopyBasisChoice0[{i},{j}],{i,1,3},{j,1,3}]

OK!

Compute the double-copy

DoubleCopyBasisChoice0[{1},{1}]

This is the special Galileon 4-pt amplitude proportional to s t u.

PROBLEM 1e part 1: χPT with a leading h.d. correction: quadratic order

The χPT amplitude must be cyclic and obey trace reversal, so
g(s,t) = A4[1234]=A4[2341] = g(u,t)
i.e. cyclicity says that the amplitude must be symmetric in s and u.

Trace reversal:
g(s,t) = A4[1234]=A4[1432] = g(u,t)
give no further constraint.

At quadratic order in the Mandelstams we can then have (t^2) or s u

A4χPT1234hd[s_,t_]:=c0 t+ c1 (t^2)+ c2 s u/.u->-s-t

A4χPT1243hd[s_,t_]:=A4χPT1234hd[s,-s-t]

A4χPT1324hd[s_,t_]:=A4χPT1234hd[t,s]

A4χPTvechd={A4χPT1234hd[s,t],A4χPT1243hd[s,t],A4χPT1324hd[s,t]};

Simplify[nullU1.A4χPTvechd]

This requires c2 = 2 c1

Simplify[nullU1.A4χPTvechd/.c2->2c1]

BCJ condition

Simplify[nullBCJ.A4χPTvechd]

Simplify[nullBCJ.A4χPTvechd/.c2->2c1]

No solution unless c1 = 0 = > c2 = 0

SO: the standard field theory KKBCJ relations do NOT allow any corrections to χPT of the form (d^4)(ϕ^2)

PROBLEM 1e part 2: χPT with a leading h.d. correction: cubic order

The χPT amplitude must be cyclic and obey trace reversal, so
g(s,t) = A4[1234]=A4[2341] = g(u,t)
i.e. cyclicity says that the amplitude must be symmetric in s and u.

Trace reversal:
g(s,t) = A4[1234]=A4[1432] = g(u,t)
give no further constraint.

At quadratic order in the Mandelstams we can then have (t^3) or s t u

A4χPT1234hd[s_,t_]:=c0 t+ b1 (t^3)+ b2 s t u/.u->-s-t

A4χPT1243hd[s_,t_]:=A4χPT1234hd[s,-s-t]

A4χPT1324hd[s_,t_]:=A4χPT1234hd[t,s]

A4χPTvechd={A4χPT1234hd[s,t],A4χPT1243hd[s,t],A4χPT1324hd[s,t]};

Simplify[nullU1.A4χPTvechd]

This requires b2 = -b1

Simplify[nullBCJ.A4χPTvechd/.b2->-b1]

This ALSO solves BCJ, so now we have a solution with a single cubic operator matrix element allowed

Simplify[A4χPT1234hd[s,t]/.b2->-b1]

A4χPTvechdKKBCJ=Simplify[{A4χPT1234hd[s,t],A4χPT1243hd[s,t],A4χPT1324hd[s,t]}/.b2->-b1]

Double - copy it:

DoubleCopyBasisChoicehd[Lco_,Rco_]:=Simplify[Table[A4χPTvechdKKBCJ[[α]],{α,Lco}].(Inverse[DefMinor[Rco,Lco]/.F1->f1BAS/.F2->f2BAS].Table[A4χPTvechdKKBCJ[[β]],{β,Rco}])]

Test basis indep

Table[DoubleCopyBasisChoicehd[{1},{1}]-DoubleCopyBasisChoicehd[{i},{j}],{i,1,3},{j,1,3}]

OK!

Simplify[Expand[DoubleCopyBasisChoicehd[{1},{1}]]]

Extract each order

Simplify[Expand[DoubleCopyBasisChoicehd[{1},{1}]]-(-(((c0^2) s t u)/(g^2))-(1/( (g^2)))c0 b1 s t u((s^2)+(t^2)+(u^2))-(1/( 4 (g^2)))(b1^2) s t u ((((s^2)+(t^2)+(u^2)))^2))/.u->-s-t]

This is the special Galileon 4-pt amplitude L ~dϕ dϕ + c0 (d^6)(ϕ^4)+c0 b1 (d^10)(ϕ^4)+ (b1^2)(d^14)(ϕ^4)

PROBLEM 2: BAS + (ϕ^4)

Solve Rank 2 conditions

f1test1[s_,t_]:=(((g^2)/s)+((g^2)/(-s-t)))+(1/(Λ^2))a1

f2test1[s_,t_]:=-((g^2)/s)+(1/(Λ^2))a2

Simplify[Det[The3x3matrix]/.F1->f1test1/.F2->f2test1]

Solve[Thread[Flatten[Table[Simplify[Det[The3x3matrix]/.F1->f1test1/.F2->f2test1]/.stNumerics[10+i],{i,1,5}]]==0],a2]

Rank2SolA={a2->a1};

Rank2SolB={a2->-(a1/2)};

Test rank

MatrixRank[The3x3matrix/.F1->f1test1/.F2->f2test1/.Rank2SolA]

MatrixRank[The3x3matrix/.F1->f1test1/.F2->f2test1/.Rank2SolB]

Now take a look at the determinants of the 2x2 minors.

FullSimplify[Det[DefMinor[{1,2},{1,2}]/.F1->f1test1/.F2->f2test1/.Rank2SolA]]

Simplify[Det[DefMinor[{1,2},{1,2}]/.F1->f1test1/.F2->f2test1/.Rank2SolB]]

Both cases look like they will have unphysical poles in the kernel.

The3x3matrixCase1A=Simplify[The3x3matrix/.F1->f1test1/.F2->f2test1/.Rank2SolA];

The3x3matrixCase1B=Simplify[The3x3matrix/.F1->f1test1/.F2->f2test1/.Rank2SolB];

Transpose[The3x3matrixCase1A]-The3x3matrixCase1A

Transpose[The3x3matrixCase1B]-The3x3matrixCase1B

So L and R null vectors are the same

Problem 2a: Null Vectors Sol A

So the usual KK trace reversal identities do hold!

Usual U(1) decoupling identity does NOT hold for a1 \ne 0.

Simplify[The3x3matrixCase1A.{1,1,1}]

Try a modified version

PREnullA={1,w1,w2};

Simplify[Solve[Thread[Simplify[The3x3matrixCase1A.PREnullA]==0],{w1,w2}]]

nullA=PREnullA/.{w1->((-s+t)/(2 s+t)),w2->-((s+2 t)/(2 s+t))}

Simplify[-((s+2 t)/(2 s+t))nullU1+nullBCJ(1+((s+2 t)/(2 s+t)))]

nullA-Simplify[-((s+2 t)/(2 s+t))nullU1+nullBCJ(1+((s+2 t)/(2 s+t)))]

Simplify[The3x3matrixCase1A.nullA]

Simplify[nullA.The3x3matrixCase1A]

Now we have a generalized BCJ / U(1) decoupling null vector!

What about the “old” field theory  BCJ identity?

nullBCJ

Simplify[The3x3matrixCase1A.nullBCJ]

Only OK for a1 = 0

Problem 2b: Null Vectors Sol B

So the usual KK trace reversal identities do hold!

Test a modified version of the U(1) decoupling identity

nullB={1,1,1};

Simplify[The3x3matrixCase1B.nullB]

Usual U(1) decoupling holds

The field theory BCJ identity?

Simplify[The3x3matrixCase1B.nullBCJ]

Only OK for a1 = 0

PROBLEM 2: Apply rank 2 to χPT

Generalized χPT: cyclic inv ansatz

A4χPT1234[s_,t_]:=c0 t+ c1 (t^2)+ c2 s u/.u->-s-t

A4χPT1243[s_,t_]:=A4χPT1234[s,-s-t]

A4χPT1324[s_,t_]:=A4χPT1234[t,s]

A4χPTvec={A4χPT1234[s,t],A4χPT1243[s,t],A4χPT1324[s,t]};

Problem 2a: Generalized χPT: Generalized KKBCJ for Sol A

Simplify[A4χPTvec.nullA]

solKKBCJA=Flatten[Solve[Simplify[A4χPTvec.nullA]==0,c2]]

Simplify[A4χPTvec.nullA/.solKKBCJA]

FullSimplify[A4χPTvec[[1]]/.solKKBCJA]

c0 t+c1 ((s^2)+s t+(t^2))

Comment:  So the leading order χPT amplitude passes and so does the O((p^4)) contribution. The latter is UNLIKE the standard field theory KKBCJ relations which did not admit the O((p^4)) contribution.

Comment': Why was χPT still allowed at leading order? Because the new null vector is a linear combination of the old two ones.

Problem 2a: Double - copy Sol A

DoubleCopyBasisChoiceSolA[Lco_,Rco_]:=Table[A4χPTvec[[α]],{α,Lco}].(Inverse[DefMinor[Rco,Lco]/.F1->f1test1/.F2->f2test1/.Rank2SolA].Table[A4χPTvec[[β]],{β,Rco}])/.solKKBCJA

The kernel as a spurious pole at (s + 2 t) = 0. Uh! Does it go away in the double-copy?

FullSimplify[Det[DefMinor[{1,2},{1,2}]/.F1->f1test1/.F2->f2test1/.Rank2SolA]]

FullSimplify[Simplify[DoubleCopyBasisChoiceSolA[{1,2},{1,2}]]]

yes, the spurious pole does cancel!

It *is* local, whoa! Both true for the leading χPT amplitude and for O((p^4)) contribution.

Now check basis independence

SetsOf2=Subsets[{1,2,3},{2}];

Simplify[Table[DoubleCopyBasisChoiceSolA[{1,2},{1,2}]-DoubleCopyBasisChoiceSolA[ii,jj],{ii,SetsOf2},{jj,SetsOf2}]]

OK!

Simplify[DoubleCopyBasisChoiceSolA[{1,3},{1,3}]]

Comments:
This rank 2 double-copy relation gives Spec Gal + an O((p^8)) correction, i.e.
L~dϕdϕ+(d^6)(ϕ^4)+(c1^2) (d^8)(ϕ^4)
This is a subleading correction compared with the standard BAS double-copy.In other words, the rank 2 double copy has produced an operator (d^8)(ϕ^4) that was NOT present in the standard field theory double-copy.

Problem 2b: Generalized χPT: Generalized KKBCJ for Sol B

A4χPTvec[[1]]

Simplify[A4χPTvec.nullB]

solKKBCJB=Flatten[Solve[Simplify[A4χPTvec.nullB]==0,c2]]

FullSimplify[A4χPTvec[[1]]/.solKKBCJB]

Simplify[c0 t+c1 (-2 (s^2)-2 s t+(t^2))/.c1->-((a1 c0)/(6 (g^2) (Λ^2)))]

Problem 2b: Double - copy Sol B

solKKBCJB

DoubleCopyBasisChoiceSolB[Lco_,Rco_]:=Table[A4χPTvec[[α]],{α,Lco}].(Inverse[DefMinor[Rco,Lco]/.F1->f1test1/.F2->f2test1/.Rank2SolB].Table[A4χPTvec[[β]],{β,Rco}])/.solKKBCJB

Simplify[DoubleCopyBasisChoiceSolB[{1,2},{1,2}]]/.c1->0

Oh no! This double - copy gives spurious poles instead of spec Gal. 
   
BUT... perhaps we are supposed to also include the h.d. corrections with coefficient c1... can we cancel the spurious poles with some particular choice of c1?

FullSimplify[DoubleCopyBasisChoiceSolB[{1,2},{1,2}]]

That looks like a mess... let’s Find the location of the spurious poles

Simplify[Solve[(a1 (3 a1 s t (s+t)+4 (g^2) ((s^2)+s t+(t^2)) (Λ^2)))==0,s]]

Plug into the numerator of the double-copy: we want that to be zero, so the spurious poles are actually cancelled for some choice of c1:

Simplify[Simplify[(a1 (3 a1 s t (s+t)+4 (g^2) ((s^2)+s t+(t^2)) (Λ^2)))DoubleCopyBasisChoiceSolB[{1,2},{1,2}]]/.s->-((3 a1 (t^2)+4 (g^2) t (Λ^2)+(Sqrt[3]) (Sqrt[(t^2) (3 (a1^2) (t^2)-8 a1 (g^2) t (Λ^2)-16 (g^4) (Λ^4))]))/(6 a1 t+8 (g^2) (Λ^2)))]

Simplify[Simplify[(3 a1 s t (s+t)+4 (g^2) ((s^2)+s t+(t^2)) (Λ^2))DoubleCopyBasisChoiceSolB[{1,2},{1,2}]]/.s->((-3 a1 (t^2)-4 (g^2) t (Λ^2)+(Sqrt[3]) (Sqrt[(t^2) (3 (a1^2) (t^2)-8 a1 (g^2) t (Λ^2)-16 (g^4) (Λ^4))]))/(6 a1 t+8 (g^2) (Λ^2)))]

Yes! We can get rid of the spurious poles by choosing

Simplify[Solve[(a1 c0 g+6 c1 (g^3) (Λ^2))==0,c1]]

What is left then?

Simplify[DoubleCopyBasisChoiceSolB[{1,2},{1,2}]/.c1->-((a1 c0)/(6 (g^2) (Λ^2)))]

What a nice result : a local expression.

Let’s dissect it:

Simplify[(((c0^2) (9 (g^2) s t (s+t)+((a1 ((((s^2)+s t+(t^2)))^2))/(Λ^2))))/(9 (g^4)))-(-(((c0^2) s t u)/( (g^2)))+((a1 (c0^2) ((((s^2)+(t^2)+(u^2)))^2))/(36 (g^4) (Λ^2))))/.u->-s-t]

Comment:   This is the Spec Galileon + a1 (d^8)(ϕ^4). Note here that the coefficient of the (d^8)(ϕ^4) is fixed in terms of the Galileon coupling and the kernel parameter a1. This is unlike Case A where (d^8)(ϕ^4) had a free parameter, unrelated to a1.

Check basis independence

SetsOf2=Subsets[{1,2,3},{2}];

Simplify[Table[DoubleCopyBasisChoiceSolB[{1,2},{1,2}]-DoubleCopyBasisChoiceSolB[ii,jj],{ii,SetsOf2},{jj,SetsOf2}]]

PROBLEM 2c

Solution A with a2 = a1: 
the (ϕ^4) contributions enters all (Subscript[m, 4]) amplitudes in the same way, so its group theory structure must be (d^abcd), i.e. it is of the form (d^abcd)(d^(a'b'c'd'))(ϕ^(aa'))(ϕ^(bb'))(ϕ^(cc'))(ϕ^(dd')). The presence of (d^abcd) violate the U(1) decoupling identity, so that’s why it no longer holds, but we get a new null vector that modifies U(1) / BCJ from field theory.

Solution B with a2->-(a1/2):
we found that the U(1) decoupling identity continues to hold, so that makes us suspect that the  (ϕ^4) interaction is build out of contractions with the antisymmetric structure constants (f^abc). Something like  (f^abx)(f^cdx)(f^(a'b'y))(f^(c'd'y))(ϕ^(aa'))(ϕ^(bb'))(ϕ^(cc'))(ϕ^(dd')).

PROBLEM 2d: Apply rank 2 to YM

YM ++-- ansatz

Let' s make an ansatz for the ++-- and + -+- components of the amplitude, including some higher - derivative corrections . (It is non - trivial that the higher derivative corrections can be written with an overall factor of  (([12])^2)<34((>)^2) but it can be shown to be true.)

NϵYM=3;

1234 ordering can have poles in the s and u channels, but not in t.

A4YMppmm1234[s_,t_]:=((ang[3,4])^2)((sq[1,2])^2)(((gYM^2)/(s u))-((t (gF3^2))/(s (Λ^4)))(ϵ^2)+Sum[(Λ^(-2k))e[k,r](s^(r-1))(t^(k-r-1))(ϵ^k),{k,2,NϵYM},{r,1,k-1}])/.u->-s-t

Simplify[Series[A4YMppmm1234[s,t]/(((ang[3,4])^2)((sq[1,2])^2)),{ϵ,0,3}]]

A4YMppmm1243[s_,t_]:=A4YMppmm1234[s,-s-t]

YM +-+- ansatz

1324 ordering can have poles in the t and u channels, but not in s.

A4YMpmpm1324[s_,t_]:=((ang[3,4])^2)((sq[1,2])^2)(((gYM^2)/(t u))+Sum[(Λ^(-2k))h[k,r](s^(r-1))(t^(k-r-1))(ϵ^k),{k,2,NϵYM},{r,1,k-1}])/.u->-s-t

Simplify[Series[A4YMpmpm1324[s,t]/(((ang[3,4])^2)((sq[1,2])^2)),{ϵ,0,3}]]

Trace-reversal requires A[(SuperPlus[1]),(SuperMinus[3]),(SuperPlus[2]),(SuperMinus[4])] = A[(SuperPlus[1]),(SuperMinus[4]),(SuperPlus[2]),(SuperMinus[3])] = A[(SuperPlus[1]),(SuperMinus[3]),(SuperPlus[2]),(SuperMinus[4])] with (3<->4)

so this means A[(SuperPlus[1]),(SuperMinus[3]),(SuperPlus[2]),(SuperMinus[4])]  has to be symmetric in u and t

Simplify[(A4YMpmpm1324[s,t]-A4YMpmpm1324[s,-s-t])/(((ang[3,4])^2)((sq[1,2])^2))]

i . e . we must take h[3, 1] = 0

Cyclicity says 

     A4YMpmpm1324(s,t)
     =A4YMpmpm2413(s,t)
     =A4YMpmpm1324(s,t)|_{1<->2, 4<->3}
     =A4YMpmpm1324(s,t). 

So no additional constraints.

YM 6-comp vector

A4YMMHVvec={A4YMppmm1234[s,t],A4YMppmm1243[s,t],A4YMpmpm1324[s,t]}/.h[3,1]->0;

Generalized YM: Generalized KKBCJ for Sol A

condU1A=Simplify[A4YMMHVvec.nullA/(((ang[3,4])^2)((sq[1,2])^2) )]/.ϵ->1

solYMMHVcaseA=Flatten[Solve[Thread[Flatten[Table[condU1A/.stNumerics[10+i],{i,1,5}]]==0]]]

FullSimplify[A4YMMHVvec[[1]]/.solYMMHVcaseA]/(((ang[3,4])^2)((sq[1,2])^2) )/.ϵ->0

YM and (F^3) pass of course b/c it is just usual KK relations

FullSimplify[A4YMMHVvec[[1]]-((ang[3,4])^2)((sq[1,2])^2) (-((gYM^2)/(s (s+t)))-((t (gF3^2))/(s (Λ^4)))(ϵ^2))/.solYMMHVcaseA]/(((ang[3,4])^2)((sq[1,2])^2) )

FullSimplify[A4YMMHVvec[[2]]-((ang[3,4])^2)((sq[1,2])^2) (((gYM^2)/(s t))-((u (gF3^2))/(s (Λ^4)))(ϵ^2))/.solYMMHVcaseA/.u->-s-t]/(((ang[3,4])^2)((sq[1,2])^2) )

FullSimplify[A4YMMHVvec[[3]]-((ang[3,4])^2)((sq[1,2])^2) (((gYM^2)/(u t)))/.solYMMHVcaseA/.u->-s-t]/(((ang[3,4])^2)((sq[1,2])^2) )

Note that the + -+- got fully fixed in terms of ++-- as one would expect from amplitudes arising from a single Lagrangian

Generalized YM: Generalized KKBCJ for Sol B

condU1B=Simplify[A4YMMHVvec.nullB/(((ang[3,4])^2)((sq[1,2])^2) )]/.ϵ->1

solYMMHVcaseB=Flatten[Solve[Thread[Flatten[Table[condU1B/.stNumerics[10+i],{i,1,5}]]==0]]]

FullSimplify[A4YMMHVvec[[1]]/.solYMMHVcaseB]/(((ang[3,4])^2)((sq[1,2])^2) )/.ϵ->0

YM passes too! (as expected...)

FullSimplify[A4YMMHVvec[[1]]-((ang[3,4])^2)((sq[1,2])^2) (-((gYM^2)/(s (s+t)))-((t (gF3^2))/(s (Λ^4)))(ϵ^2))/.solYMMHVcaseB]/(((ang[3,4])^2)((sq[1,2])^2) )

YM x YM Double - copy Sol A

DoubleCopyBasisChoiceSolA[Lco_,Rco_]:=Table[A4YMMHVvec[[α]],{α,Lco}].(Inverse[DefMinor[Rco,Lco]/.F1->f1test1/.F2->f2test1/.F6->f6test1/.Rank2SolA].Table[A4YMMHVvec[[β]],{β,Rco}])/.solYMMHVcaseA

Simplify[Series[Simplify[DoubleCopyBasisChoiceSolA[{1,2},{1,2}]],{ϵ,0,6}]/(((ang[3,4])^4) ((sq[1,2])^4))]

This gives gravity and the usual pole terms from (F^3) double-copy. Plus higher order terms. BUT nothing is non-local => everything is local.

Check basis independence

SetsOf2=Subsets[{1,2,3},{2}];

Simplify[Table[DoubleCopyBasisChoiceSolA[{1,2},{1,2}]-DoubleCopyBasisChoiceSolA[ii,jj],{ii,SetsOf2},{jj,SetsOf2}]]

So Basis indep OK

YM x YM Double - copy Sol B

DoubleCopyBasisChoiceSolB[Lco_,Rco_]:=Table[A4YMMHVvec[[α]],{α,Lco}].(Inverse[DefMinor[Rco,Lco]/.F1->f1test1/.F2->f2test1/.F6->f6test1/.Rank2SolB].Table[A4YMMHVvec[[β]],{β,Rco}])/.solYMMHVcaseB

Test Basis indep

Simplify[Table[DoubleCopyBasisChoiceSolB[{1,2},{1,2}]-DoubleCopyBasisChoiceSolB[ii,jj],{ii,SetsOf2},{jj,SetsOf2}]]

Look at double - copy result with only YM

Simplify[Series[Simplify[DoubleCopyBasisChoiceSolB[{1,2},{1,2}]],{ϵ,0,0}]/(((ang[3,4])^4) ((sq[1,2])^4))]

Yikes, looks like spurious pole troubles

But ... what if we  treat a1 as a perturbation, i.e. we expand in small a1...?

Simplify[Series[Simplify[DoubleCopyBasisChoiceSolB[{1,2},{1,2}]]/.a1->a1 ϵ,{ϵ,0,2}]/(((ang[3,4])^4) ((sq[1,2])^4))]

Then the leading term is sensible, but the subleading terms with the ((s^2)+s t+(t^2)) poles are not...

So keep a1 finite and see if higher-order terms in the YM amp can fix this

expr0=Simplify[Normal[Series[Simplify[DoubleCopyBasisChoiceSolB[{1,2},{1,2}]],{ϵ,0,2}]/(((ang[3,4])^4) ((sq[1,2])^4))]/.ϵ->1]

Simplify[Solve[(3 a1 s t (s+t)+4 (g^2) ((s^2)+s t+(t^2)) (Λ^2))==0,s]]

shouldvanish1=FullSimplify[s t (s+t) (Λ^2) (3 a1 s t (s+t)+4 (g^2) ((s^2)+s t+(t^2)) (Λ^2))expr0/.s->-((3 a1 (t^2)+4 (g^2) t (Λ^2)+(Sqrt[3]) (Sqrt[(t^2) (3 (a1^2) (t^2)-8 a1 (g^2) t (Λ^2)-16 (g^4) (Λ^4))]))/(6 a1 t+8 (g^2) (Λ^2)))]

shouldvanish2=FullSimplify[s t (s+t) (Λ^2) (3 a1 s t (s+t)+4 (g^2) ((s^2)+s t+(t^2)) (Λ^2))expr0/.s->((-3 a1 (t^2)-4 (g^2) t (Λ^2)+(Sqrt[3]) (Sqrt[(t^2) (3 (a1^2) (t^2)-8 a1 (g^2) t (Λ^2)-16 (g^4) (Λ^4))]))/(6 a1 t+8 (g^2) (Λ^2)))]

Simplify[shouldvanish1+shouldvanish2]

Only solution is setting gYM = 0. Then

shouldvanish1/.gYM->0

shouldvanish2/.gYM->0

expr1=Simplify[Series[Simplify[DoubleCopyBasisChoiceSolB[{1,2},{1,2}]],{ϵ,0,4}]/(((ang[3,4])^4) ((sq[1,2])^4))/.gYM->0]

shouldvanishB1=FullSimplify[s t (s+t) (Λ^2) (3 a1 s t (s+t)+4 (g^2) ((s^2)+s t+(t^2)) (Λ^2))expr1/.s->-((3 a1 (t^2)+4 (g^2) t (Λ^2)+(Sqrt[3]) (Sqrt[(t^2) (3 (a1^2) (t^2)-8 a1 (g^2) t (Λ^2)-16 (g^4) (Λ^4))]))/(6 a1 t+8 (g^2) (Λ^2)))]

shouldvanishB2=FullSimplify[s t (s+t) (Λ^2) (3 a1 s t (s+t)+4 (g^2) ((s^2)+s t+(t^2)) (Λ^2))expr1/.s->((-3 a1 (t^2)-4 (g^2) t (Λ^2)+(Sqrt[3]) (Sqrt[(t^2) (3 (a1^2) (t^2)-8 a1 (g^2) t (Λ^2)-16 (g^4) (Λ^4))]))/(6 a1 t+8 (g^2) (Λ^2)))]

Simplify[shouldvanishB1+shouldvanishB2]

Solve[Thread[Table[Normal[Simplify[shouldvanishB1+shouldvanishB2]]/((1/(a1 (Λ^4) (((3 a1 t+4 (g^2) (Λ^2)))^2)))12 (t^5))/.ϵ->1/.stNumerics[34+i],{i,1,10}]==0],{e[2,1],gF3}]

expr1/.{e[2,1]->0,gF3->0}

No non - trivial solutions...

Could try to include higher orders... 

ahr, let’s just do it!

expr2=Simplify[Normal[Simplify[Series[Simplify[DoubleCopyBasisChoiceSolB[{1,2},{1,2}]],{ϵ,0,6}]/(((ang[3,4])^4) ((sq[1,2])^4))]]/.ϵ->1];

shouldvanishC1=FullSimplify[(3 a1 s t (s+t)+4 (g^2) ((s^2)+s t+(t^2)) (Λ^2))expr2/.s->-((3 a1 (t^2)+4 (g^2) t (Λ^2)+(Sqrt[3]) (Sqrt[(t^2) (3 (a1^2) (t^2)-8 a1 (g^2) t (Λ^2)-16 (g^4) (Λ^4))]))/(6 a1 t+8 (g^2) (Λ^2)))];

shouldvanishC2=FullSimplify[(3 a1 s t (s+t)+4 (g^2) ((s^2)+s t+(t^2)) (Λ^2))expr2/.s->((-3 a1 (t^2)-4 (g^2) t (Λ^2)+(Sqrt[3]) (Sqrt[(t^2) (3 (a1^2) (t^2)-8 a1 (g^2) t (Λ^2)-16 (g^4) (Λ^4))]))/(6 a1 t+8 (g^2) (Λ^2)))];

(a1 (Λ^8) (((3 a1 g t+4 (g^3) (Λ^2)))^2))Simplify[shouldvanishC1+shouldvanishC2]

Solve[Thread[Table[(a1 (Λ^8) (((3 a1 g t+4 (g^3) (Λ^2)))^2))Simplify[shouldvanishC1+shouldvanishC2]/.stNumerics[34+i],{i,1,10}]==0],{gYM,gF3,e[2,1],e[3,1],e[3,2]}]

Simplify[shouldvanishC1/.{gYM->0,e[2,1]->0,e[3,1]->-((3 a1 (gF3^2))/(4 (g^2))),e[3,2]->-((a1 (gF3^2))/(2 (g^2)))}]

Simplify[shouldvanishC2/.{gYM->0,e[2,1]->0,e[3,1]->-((3 a1 (gF3^2))/(4 (g^2))),e[3,2]->-((a1 (gF3^2))/(2 (g^2)))}]

Now there, that' s a solution ...

Simplify[expr2/.{gYM->0,e[2,1]->0,e[3,1]->-((3 a1 (gF3^2))/(4 (g^2))),e[3,2]->-((a1 (gF3^2))/(2 (g^2)))}]

Simplify[(((gF3^4) (a1 s ((s^2)+3 s t+3 (t^2))+4 (g^2) t (s+t) (Λ^2)))/(4 (g^4) s (Λ^10)))-(((-(gF3^4) t u)/((g^2) s (Λ^8)))+((a1 (gF3^4))/(4 (g^4) (Λ^10)))((s^2)-3t u))/.u->-s-t]

What is this??

Well, tr (F^(3 )) has matrix elements +++ and ---. They’ll double copy to (R^3) matrix elements with helicities +++ and ---. The tu/s pole term is exactly what you’d get from a graviton exchange between two (R^3) vertices. Due to the helicities, there can only be an s-pole: (+++)-(+-)(---)

The local term [12]^4 < 34 ((>)^2) ((s^2)-3t u) is a local matrix element of some operator (D^4)(R^4). It has proper Bose symmetry for the identical +gravitons and -gravitons, respectively. 

The question here is: how does it make sense to have an input 4-pt amplitude with a pole from (F^3) vertices and exchange of a gluon... how can we have an (F^2) to get a propagator without the gluon self-interactions? Likewise, how can we have (R^(3 )) interactions and graviton exchange without having the usual universal gravity?

These models would have to arise as some  decoupling limits of proper theories and that is a bit unusual. You can think of the vector theory as a global color-labeled Maxwell theory with a (F^3) (for a single Maxwell field (F^(3 )) vanishes, we need an adjoint structure to dress the photon fields with but it cannot be gauged because we have gYM=0). Similarly one would have to figure out some scaling limit that sends κ -> 0 while keeping the (R^(3 )) . It is not clear at all if such a model makes sense. Likewise, it is not clear that our rank 2 double-copy procedures work at 5-pt. If they do, one can try to make sense of the models involved. If not, there is a lot less motivation for exploring them further. 

Hope you had fun exploring the generalized double-copy. There are lots of different modifications and some are better motivated than others. But now you have gotten your hands dirty with the method and you are ready to conduct your own double-copy experiments. Enjoy!